Sstrhsrtj

I need to removing trailing commas based on the record_type (1st field). Input file has 50 delimiters, I need reduce them based on the record type. IF 1st field is 400, remove last 10 delimiters, if 300 remove 5 delimiters, if 210 remove 2 commas. The pattern of 400, 300 and 210 repeats and the order has to me maintained.

For example:

400,"100.00",,,,"31",,,,"510","410","0102","023",,,,,,,,,,,,,,,,,,,,,,,,,,,,,,

300,"110","1",,"2016-04-15",,,"52706","TESTFR1","100.00","1.00",,,"N",,,,,,,,,

210,"6876262",,"23 Rue du Roule",,,"PARIS","DF","75001","FR",,,,,,,,,,,,,,,,,,

I need the output as

400,"100.00",,,,"31",,,,"510","410","0102","023",,,,,,,,,,,,,,,,,,,,

300,"110","1",,"2016-04-15",,,"52706","TESTFR1","100.00","1.00",,,"N",,,,

210,"6876262",,"23 Rue du Roule",,,"PARIS","DF","75001","FR",,,,,,,,,,,,,,,,

I tried awk and sed but they are truncating the whole file.

Sed can meet your requirements. This will match the desired beginning of the string, and then remove the desired number of commas from the end.

sed -e '/^400/ s/,{10}$//' -e '/^300/ s/,{5}$//' -e '/^210/ s/,{2}$//' 

AWK approach. We define trunk function to print a sub-string of the whole line, from index 0 to index length - n characters. The rest is simply pattern matching, and calling trunk function with appropriate number of characters to be removed.

As one liner :

$ awk -F ',' 'function trunk(n){print substr($0,0,length($0)-n)}; $1==400{trunk(10)};$1==300{trunk(5)};$1==210{trunk(2)} ' input.txt 

From a script this would be like so:

#!/usr/bin/awk -f



BEGIN { FS="," };



function trunk(n){

    print substr($0,0,length($0)-n)

}; 



$1==400{ trunk(10)};

$1==300{trunk(5)};

$1==210{trunk(2)};

And here it is in action:

$ ./trunk_lines.awk input.txt                                                                                            

400,"100.00",,,,"31",,,,"510","410","0102","023",,,,,,,,,,,,,,,,,,,,

300,"110","1",,"2016-04-15",,,"52706","TESTFR1","100.00","1.00",,,"N",,,,

210,"6876262",,"23 Rue du Roule",,,"PARIS","DF","75001","FR",,,,,,,,,,,,,,,,

Given that the trailing fields are empty (or if you want to delete them as well)

awk -F, -vOFS=, '$1=="400"{NF-=10} $1=="300"{NF-=5} $1=="210"{NF-=2} 1' file 

or if you want to be clever (which can be both a good and bad thing)

awk -F, -vOFS=, 'BEGIN{x[400]=10;x[300]=5;x[210]=2} {NF-=x[$1]} 1' file